4 replies to this topic

[Kathy]

Hey there. I've just purchased Ad-Aware SE Pro & ran a full scan. I'm running XP Home. Now I'm having trouble opening programs & files. Some (not all) of the icons on my desktop look like little web page icons. When I click on them, I get the message: Windows cannot open this file: File: Palm Desktop.lnk What do you want to do? Use web to find....or...select the progam from list.
Same thing happens when I try to open a program from the start/program list. Windows says it cannot open .exe files. I've tried "run", but no matter what I type in, it won't open.
Please help me fellas.

Thanks- Kathy

[LS SteveJ (former LS employee)]

Hey there. I've just purchased Ad-Aware SE Pro & ran a full scan. I'm running XP Home. Now I'm having trouble opening programs & files. Some (not all) of the icons on my desktop look like little web page icons. When I click on them, I get the message: Windows cannot open this file: File: Palm Desktop.lnk What do you want to do? Use web to find....or...select the progam from list.
Same thing happens when I try to open a program from the start/program list. Windows says it cannot open .exe files. I've tried "run", but no matter what I type in, it won't open.
Please help me fellas.

Thanks- Kathy

Hey Kathy

Which version number of Ad-Aware are you using?

[Corrine]

Hi, Kathy. Looks like you have Ad-Watch set to "Lock executable file associations" and on "automatic". This has been an ongoing problem since Ad-Aware SE was released.

From the Help file:

You can lock the startup sections of your registry, block possible and actual browser hijack attempts, block suspicious processes, lock executable file associations, Block malicious cookies, block Pop-ups, and uses the all new CSI technology to protect you from unknown variants as well. Even if Ad-Watch is turned off and something DOES install onto your system, it will recognize it and will kill the process as soon as it has seen it when turned back on. Emphasis added

Thus, Ad-Watch is doing precisely as you have instructed it to do -- it has locked executable file associations. Personally, I want to know what is going on with my PC and have "automatic" turned off with Ad-Watch. When I install software and am prompted by Ad-Watch to accept a change, I know it is safe to allow. However, should something slip past my defenses and try to make changes without my permission, Ad-Watch will let me know and I can have that change blocked.

The following was prepared by Appetiser in 2004 when this problem first appeared. So that it is easier to read, I will copy/paste rather than quote the instructions.

You may also want to review:

Kelly's Korner, HOW TO: Specify the Program Used to Open Certain File Types
Kelly's Korner, Line 146, Retrieve the Class Name for a File Extension
Microsoft KB Article, HOW TO: Specify the Program Used to Open Certain Types of Files in Windows XP

For XP: Windows® XP File Association Fixes (lines 7 and 15)
http://www.dougknox..../file_assoc.htm

Restoring file associations

To make things easy to navigate I would suggest creating a new folder called c:\regfixes. Then browse to Doug Knox's web site and download all the file association fixes from http://www.dougknox..../file_assoc.htm for file types you are having problems with to this folder. As a minimum I would download com, lnk, reg then unzip each file you have downloaded.

Right mouse click on the Ad-Watch icon in the system tray and select "Ad-Watch Settings". At the bottom of the Ad-Watch window make sure automatic is not checked i.e. it is a red cross.

First you will need to restore the .exe file association. In Notepad create a new file and enter all the text the the code box below:

' VBScript to restore .exe file association with Windows XP 
Option Explicit

Dim strComputer
Dim objRegistry,objDictionary

strComputer = "."
Set objRegistry=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" &_ 
	strComputer & "\root\default:StdRegProv")
	
Set objDictionary = CreateObject("Scripting.Dictionary")
	objDictionary.Add "HKCR",&h80000000

Call RegAddString( "HKCR", ".exe", "", "exefile")
Call RegAddString( "HKCR", ".exe", "Content Type",_
  "application/x-msdownload" )
Call RegAddString( "HKCR", ".exe\PersistentHandler", "",_
  "{098f2470-bae0-11cd-b579-08002b30bfeb}" )
Call RegAddString( "HKCR", "exefile", "", "Application" )
Call RegAddBinary( "HKCR", "exefile", "EditFlags", "38,07,00,00" )
Call RegAddString( "HKCR", "exefile", "TileInfo",_
  "prop:FileDescription;Company;FileVersion" )
Call RegAddString( "HKCR", "exefile", "InfoTip",_
  "prop:FileDescription;Company;FileVersion;Create;Size" )
Call RegAddString( "HKCR", "exefile\DefaultIcon", "", "%1" )
Call RegAddString( "HKCR", "exefile\shell", "", "" )
Call RegAddString( "HKCR", "exefile\shell\open", "", "" )
Call RegAddBinary( "HKCR", "exefile\shell\open",_
  "EditFlags", "00,00,00,00" )
Call RegAddString( "HKCR", "exefile\shell\open\command", "",_
	Chr(34) & "%1" & Chr(34) & Space(1) & "%*" )
Call RegAddString( "HKCR", "exefile\shell\runas", "", "" )
Call RegAddString( "HKCR", "exefile\shell\runas\command", "",_
	Chr(34) & "%1" & Chr(34) & Space(1) & "%*" )
Call RegAddString( "HKCR", "exefile\shellex", "", "" )
Call RegAddString( "HKCR", "exefile\shellex\DropHandler",_
  "", "{86C86720-42A0-1069-A2E8-08002B30309D}" )
Call RegAddString( "HKCR", "exefile\shellex\PropertySheetHandlers", "", "" )
Call RegAddString( "HKCR", "exefile\shellex\PropertySheetHandlers\PifProps",_
	"", "{86F19A00-42A0-1069-A2E9-08002B30309D}" )
Call RegAddString( "HKCR", "exefile\shellex\PropertySheetHandlers\ShimLayer Property Page",_
	"", "{513D916F-2A8E-4F51-AEAB-0CBC76FB1AF8}" )

Function RegKeyExists(rootkey, keypath)
	Dim arrValueNames, arrValueTypes
	If objRegistry.EnumValues(objDictionary(rootkey), keypath, arrValueNames, arrValueTypes) = 0 Then
  RegKeyExists = True
	Else
  RegKeyExists = False
	End If	
End Function

Sub RegAddKey(rootkey, keypath)
	objRegistry.CreateKey objDictionary(rootkey),keypath
End Sub

Sub RegAddString(rootkey, keypath, valuename, valuedata)
	If Not RegKeyExists(rootkey, keypath) Then
  Call RegAddKey( rootkey, keypath )
	End If
	objRegistry.SetStringValue objDictionary(rootkey),keypath,valuename,valuedata
End Sub

Sub RegAddBinary(rootkey, keypath, valuename, valuearray)
	Dim arrValue(),arrHexValue,i,HexVal
   
	arrHexValue = Split(Trim(valuearray),",")
		i=0
		For Each HexVal in arrHexValue
		Redim Preserve arrValue(i)
		arrValue(i) = "&h" & HexVal
	  i=i + 1
		Next
		objRegistry.SetBinaryValue objDictionary(rootKey),keypath,valuename,arrValue
		Redim arrValue(0)
End Sub

In Notepad, select file, select save, under "save in" use the pull down menu and select c:\regfixes and for file name enter xp_exe_fix.vbs and under "Save as type" use the pull down menu and select "All files".

Navigate to c:\regfixes and right mouse click on xp_exe_fix.vbs and select open. This will run the script and restore the registry keys associated with the exe file type. If you are running Ad-Watch if it pops an alert whilst this script is running you will need to accept the update to the registry.

Now the .exe file association is restored you will be able to run regedit.exe.
Work through the file association fixes that you downloaded above from Doug Knox's site.

Press start, select run and enter the text in bold below

cmd

Click OK, this will open a command window

at the prompt in the command window enter the text in bold (please note the spaces in the command text)

regedit /s c:\regfixes\xp_com_fix.reg

adjust the path as appropriate to where you unzipped the reg files to

repeat the regedit command for the other reg files you have e.g.

xp_regfile.reg
linkfile_fix.reg

With Ad-Watch it is vital you accept any changes that may be alerted by Ad-Watch when merging these files.

Original From: http://www.lavasofts...ndpost&p=367004 (no longer available)

Good luck.

[Max]

I had the same problem when I installed Ad-watch on my Windows XP PC about a year or two ago. Lavasoft Tech Support could not help me. It turned out that Ad-Watch deleted an important registry file and I had to reinstall my Window XP system. I've never used Ad-Watch since.

[Kathy]

Hey ya'll. Steve, I don't know the version number & I can't open the program to see. I ordered a copy on CD, but haven't got it yet- I just purchased on 4/19. I can give you license code number if you want me to, if that helps you find out what version it is.
Corrine, thanks for your reply and instructions. I'm going to give it a shot. I'm not very good at this, and it can be very frustrating, but I'm determined not to reinstall windows. I just went through this very recently- due to virus, hence the new software
I worked on this till 5am and was finally able to reboot with the windows disk in and boot in safe mode with command promt. This way I was able to open the registry editor & check to see if I had the Sircam virus (I'm a little freaked out over these virus-thingys). I had checked microsoft's support site & based on my "symptoms", that is what it said I should do. Anyway, the line it said to check didn't have the wrong value in it, so I guess I don't have that virus, whew!
By the way, in regedit, the top line says "default" on the right and says "no value" on all the ones I looked at. Are they supposed to say that?
Ok, I'm giving away just how very unexperienced I am at this. All the more reason I am so very thankful for help here.
I'll get busy and post back later. Please check on me again.
Thank you Steve & Corrine


aaaaw Max, I'm sorry for your trouble. I recently lost everything on my computer. Just a reminder though, programs only do what they're told to do. Somebody must've told AdAware what to delete....
I gotta take my share of the responsibility on this, being the only human involved here. If I had it to do over again, I would have gotten more familiar with the program before running my first scan & learned how to use it. I certainly won't be ditching the program over this. AdAware comes very highly recommended by many top professionals.